Waddle_Language/grammar/operations/control_flow.bnf

<statement> ::= <assignment_statement>
              | <if_statement>
              | <while_statement>
              | <loop_statement>
              | <reverse_loop_statement>
              | <function_call_statement>
              | <return_statement>
              | <using_statement>
              | <attempt_statement>
              | <fail_statement>

<assignment_statement> ::= <my_identifier> ".set(" <expression> ")" ";"

<if_statement> ::= <if_statement_keyword> "(" <boolean_expression> ")"
    "{" <statement>* "}" 
    (<elseif_statement_keyword> "(" <boolean_expression> ")" "{" <statement>* "}")?
    (<else_statement_keyword> "{" <statement>* "}")?

<while_statement> ::= <while_loop_keyword> "(" <expression> ")"
    "{" <statement>* "}"

<loop_statement> ::= <for_loop_keyword> "(" <identifier> "," <expression> "->" <expression>
    ("," <expression>)? ")"
    "{" <statement>* "}"

<reverse_loop_statement> ::= <reverse_for_loop_keyword> "(" <identifier> "," <expression> "->" <expression>
    ("," <expression>)? ")"
    "{" <statement>* "}"

<function_call_statement> ::= <my_identifier> "(" <argument_list>? ")" ";"

<return_statement> ::= <return_statement_keyword> <expression> ";"

<using_statement> ::= <context_management_keyword> <type> <identifier> ".set(" <expression> ")"
    "{" <statement>* "}"

<attempt_statement> ::= <expression> ".attempt" "{" <attempt_handler>* "}"

<attempt_handler> ::= ("ok" | <identifier> | "error") "{" <statement>* "}"

<fail_statement> ::= <my_identifier> "." <exception_throw_keyword> "(" <error_type> ("(" <argument_list>? ")")? ")" ";"