Waddle_Language/grammar/declarations/function_declarations.bnf

<function_declaration> ::= <optional_whitespace>
                           <accessibility_modifier>
                           <function_keyword>
                           <required_single_line_whitespace>
                           <identifier>
                           <optional_whitespace>
                           <function_signature>
                           <optional_whitespace>
                           <standard_statement_block>

<function_signature> ::= "(" <parameter_list>? ")" <optional_whitespace> <arrow_keyword> <optional_whitespace> <return_type_list> <optional_whitespace> <function_error_signature>?

<function_error_signature> ::= <function_error_identifier> <required_single_line_whitespace> <error_type_list>

<return_type_list> ::= "[" <optional_single_line_whitespace> <type> | <callable_type_keyword> ( <optional_single_line_whitespace> "|" <optional_single_line_whitespace> <null_keyword>)? <optional_single_line_whitespace> "]"

<error_type_list> ::= "[" <optional_single_line_whitespace> <inherited_error_type> ("," <optional_single_line_whitespace> <inherited_error_type>)* "]"

<parameter_list> ::= <parameter_group>?

<parameter_group> ::= <optional_whitespace>
    ( <required_parameters>
    | <required_parameters> "," <default_parameters>
    | <default_parameters> )
    <optional_whitespace>

<required_parameters> ::=
    <optional_whitespace>
    ( <required_parameter>
    | <required_parameter> "," <required_parameters> )

<default_parameters> ::=
    <optional_whitespace>
    ( <default_parameter>
    | <default_parameter> "," <default_parameters> )

<required_parameter> ::= <type> <required_single_line_whitespace> <identifier>

<default_parameter> ::= <type> <required_single_line_whitespace> <identifier> ".default(" <literal> ")"

<lambda_declaration> ::= <function_keyword> <optional_whitespace> "(" <parameter_list>? ")" <function_signature> <standard_statement_block>

<constructor_declaration> ::= <optional_whitespace> <accessibility_modifier> <function_keyword> <required_single_line_whitespace> <constructor_method_name> <optional_whitespace> <function_signature> <optional_whitespace> <standard_statement_block>

<destructor_declaration> ::= <optional_whitespace> <accessibility_modifier> <function_keyword> <required_single_line_whitespace> <destructor_method_name> <optional_whitespace> <function_signature> <optional_whitespace> <standard_statement_block>